XSLT 2.0 replace < > special characters

mattmozer · Apr 25, 2005

I am trying to do a search and replace on an element with a regex. The
problem I am having is on the replace. I am looking for any http(s)
strings and needing to create an href out of it.
This code below works for replace any http(s) with say a text result
such as "fred" or "bob" - for example. You can see what I am
trying to do with it though with the a href. I am using XML Spy on a
windows platform.

<xsl:template match="whatever">
<xsl:copy>
<xsl:value-of select='replace(.,"(https?:\/\/[^\s]*)", "<a
href=$1>$1</a>")'/>
</xsl:copy>
</xsl:template>

The element in this case "whatever" could have multiple http
references and are contained in a text element of arbitrary content and
length. So, with that being said, the below example is not what I'm
looking for as someone has already pointed out. I have tried something
similar to no avail.

<xsl:template match="//addr">
<xsl:element name="a">
<xsl:attribute name="href">
<xsl:value-of select="."/>
</xsl:attribute>
<xsl:value-of select="."/>
</xsl:element>
</xsl:template>

I need to be able to escape the "<" & ">" characters or change my
approach entirely... I think this would prove to be a valuable tool if
it were to work.

-Matt

Martin Honnen · Apr 26, 2005

I am trying to do a search and replace on an element with a regex. The
problem I am having is on the replace. I am looking for any http(s)
strings and needing to create an href out of it.
This code below works for replace any http(s) with say a text result
such as "fred" or "bob" - for example. You can see what I am
trying to do with it though with the a href. I am using XML Spy on a
windows platform.

<xsl:template match="whatever">
<xsl:copy>
<xsl:value-of select='replace(.,"(https?:\/\/[^\s]*)", "<a
href=$1>$1</a>")'/>
</xsl:copy>
</xsl:template>

The element in this case "whatever" could have multiple http
references and are contained in a text element of arbitrary content and
length.

Here is an example input that I hope is what you intend to have:

<?xml version="1.0" encoding="UTF-8"?>
<root>
<p>This is a text with a link: http://www.example.com/ followed by
another link: http://www.example.org/2005/04/26</p>
</root>

Then this stylesheet

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="2.0">

<xsl

utput method="html" indent="yes" encoding="UTF-8" />

<xsl:template match="/">
<html>
<head>
<title>regular expression example</title>
</head>
<body>
<xsl:apply-templates select="//p" />
</body>
</html>
</xsl:template>

<xsl:template match="p">
<xsl:copy>
<xsl:apply-templates select="node()" mode="make-links" />
</xsl:copy>
</xsl:template>

<xsl:template match="*" mode="make-links">
<xsl:apply-templates select="." />
</xsl:template>

<xsl:template match="text()" mode="make-links">
<xsl:analyze-string select="." regex="https?://[^\s]*">
<xsl:matching-substring>
<a href="{regex-group(0)}"><xsl:value-of select="regex-group(0)"
/></a>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="." />
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:template>

</xsl:stylesheet>

gives the following output:

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=UTF-8">

<title>regular expression example</title>
</head>
<body>
<p>This is a text with a link: <a
href="http://www.example.com/">http://www.example.com/</a> followed by
another link: <a
href="http://www.example.org/2005/04/26">http://www.example.org/2005/04/26</a></p>
</body>
</html>

xslt and namespaces	2	Nov 5, 2010
Sort by number of characters	0	Nov 3, 2023
Sort by number of characters	1	Nov 2, 2023
Digesting a table with XSL 2.0	2	Mar 14, 2011
XSLT filter nodes containing attributes with known values	0	Sep 26, 2009
xsltproc question - wondering what I did wrong?	4	Apr 13, 2012
Tricky XSLT question involving variables, serializing, processinginstructions	2	Apr 2, 2009
remove specail character from xml using xslt	0	Nov 2, 2011

XSLT 2.0 replace < > special characters

mattmozer

Martin Honnen

Ask a Question

Similar Threads

Members online

Forum statistics

Latest Threads